;Title:		loadrfcdf.pro
;
;Purpose:	Script to load desired variables from the NCAR C-130 flights at SHEBA
;
;Author:	Matthew Shupe
;Date:		2/26/00
;----------------------------------------------------------------------------------


;Which variables (actual names from netCDF file)
;------------------------------------------------
vars=['XGLWC','DAY','GLAT','GLON',$
	'HGM232','HOUR','MINUTE','MONTH','SECOND',$
	'ATWH','ATX','C260X_OBL','CF300_RPO','CFSSP_LPI','CONC3_RPO',$
	'CONC6_OBL','CONCF_LPI','CONCN','CONCP_IBL','CPCAS_IBL',$
	'DBAR3_RPO','DBAR6_OBL','DBARF_LPI','DBARP_IBL','DBZ6_OBL',$
	'DBZF_LPI','OAT','PALT','PALTF','PLWC6_OBL','PLWCC','PLWCC1',$
	'PLWCF_LPI','RHUM']
varsout=['LW_G','DAY','GLAT','GLON',$
	'RALT','HOUR','MINUTE','MONTH','SECOND',$
	'ATWH','ATX','CB_2X','CB_F3','CB_F1','C_F3',$
	'C_2X','C_F1','C_CN','C_PC','CB_PC',$
	'DM_F3','DM_2X','DM_F1','DM_PC','DB_2X',$
	'DB_F1','ATO','PALT','PALTF','LW_2X','LW_K','LW_K1',$
	'LW_F1','RH']
nvars=n_elements(vars)

cd,'d:/flightdata/ncarc130/lrt',current=odir
restore,'nc130_bins.dat'
;Which netCDF files
;------------------
file=findfile('rf*.cdf',count=numfiles)

for i=4,numfiles-1 do begin
	fid=ncdf_open(file[i])
	for j=0,nvars-1 do begin
		varid=ncdf_varid(fid,vars[j])
		r=execute('ncdf_varget,fid,varid,'+varsout[j])
	endfor
	ncdf_close,fid

	;Put data in useful format
	;	(reform to remove dimensions of 1)
	;-------------------------------------
	cb_2x=reform(cb_2x)
	cb_f3=reform(cb_f3)
	cb_f1=reform(cb_f1)
	cb_pc=reform(cb_pc)

	;	(create a date stamp and time axis)
	;--------------------------------------
	datestr=strtrim(fix(month[0]),2)+'/'+strtrim(fix(day[0]),2)+'/98'
	if day[0] ne day[n_elements(day)-1] then datestr = $
		datestr+' - '+strtrim(fix(month[0]),2)+'/'+$
		strtrim(fix(day[n_elements(day)-1]),2)+'/98'
	time=hour+(day-day[0])*24. + (minute+second/60.)/60.
	;delvar,month,day,hour,minute,second

	;Save the data to IDL files
	oname=str_sep(file[i],'.')
	save,glat,glon,time,datestr,palt,paltf,ralt,atwh,atx,ato,rh,$
		cb_2x,cb_f3,cb_f1,cb_pc,c_2x,c_f3,c_f1,c_pc,c_cn,$
		dm_2x,dm_f3,dm_f1,dm_pc,lw_2x,lw_f1,lw_k,lw_k1,lw_g,$
		db_2x,db_f1,b_2x,b_f1,b_f3,b_pc,filename=oname[0]+'.dat'

endfor

cd,odir
end