;Title:		loadrfcdf.pro
;
;Purpose:	Script to load desired variables from the NCAR C-130 flights at SHEBA
;
;Author:	Matthew Shupe
;Date:		2/26/00
;----------------------------------------------------------------------------------


;Which variables (actual names from netCDF file)
;------------------------------------------------
vars=['XGLWC','XGSFC','DAY','GLAT','GLON','HOUR','MINUTE','MONTH','SECOND',$
	'ATX','C260X_OBL','CF300_RPO','CFSSP_LPI','CONC3_RPO','CONC6_OBL','CONCF_LPI',$
	'DBAR3_RPO','DBAR6_OBL','DBARF_LPI','DBZ6_OBL',$
	'DBZF_LPI','PALT','PLWC6_OBL','PLWCC','PLWCC1','PLWCF_LPI']
varsout=['LW_G','SA_G','DAY','GLAT','GLON','HOUR','MINUTE','MONTH','SECOND',$
	'ATX','CB_2X','CB_F3','CB_F1','C_F3','C_2X','C_F1',$
	'DM_F3','DM_2X','DM_F1','DB_2X',$
	'DB_F1','PALT','LW_2X','LW_K','LW_K1','LW_F1']
nvars=n_elements(vars)

cd,'/data1/sheba/fireace/ncar_c130',current=odir
restore,'nc130_bins.dat'
;Which netCDF files
;------------------
file=findfile('RF*lrt.cdf',count=numfiles)

for i=0,3 do begin
	fid=ncdf_open(file[i])
	for j=0,nvars-1 do begin
		varid=ncdf_varid(fid,vars[j])
		r=execute('ncdf_varget,fid,varid,'+varsout[j])
	endfor
	ncdf_close,fid

	;Put data in useful format
	;	(reform to remove dimensions of 1)
	;-------------------------------------
	cb_2x=reform(cb_2x)
	cb_f3=reform(cb_f3)
	cb_f1=reform(cb_f1)

	;	(create a date stamp and time axis)
	;--------------------------------------
	datestr=strtrim(fix(month[0]),2)+'/'+strtrim(fix(day[0]),2)+'/98'
	if day[0] ne day[n_elements(day)-1] then datestr = $
		datestr+' - '+strtrim(fix(month[0]),2)+'/'+$
		strtrim(fix(day[n_elements(day)-1]),2)+'/98'
	time=hour+(day-day[0])*24. + (minute+second/60.)/60.
	;delvar,month,day,hour,minute,second

	;Save the data to IDL files
	oname=str_sep(file[i],'.')
	save,glat,glon,time,datestr,palt,atx,$
		cb_2x,cb_f3,cb_f1,c_2x,c_f3,c_f1,$
		dm_2x,dm_f3,dm_f1,lw_2x,lw_f1,lw_k,lw_k1,lw_g,sa_g,$
		db_2x,db_f1,b_2x,b_f1,b_f3,filename=oname[0]+'.dat'

endfor

cd,odir
end