@echo off

rem go.bat, a windows batch file to backup 
rem the raw ctd data and process it.

rem Operation
rem Normally, five replaceable parameters 
rem will be entered in the command line.  
rem like this: 
rem go 172-05 17205 003 process batch.txt

rem First is the name of the configuration file, 
rem Second is the first part of the filename, (usually the number of the cruise), 
rem Third is the number of the cast.   
rem Fourth is the subdirecty the processed files are to be directed to.  This directory must exist.
rem Fifth is the name of the text file needed by SBEBatch.  
rem Note that this text file must be in the correct 
rem location.  (normally c:\data\ctd\%4)  

rem The processing is set up this way to provide a maximum of flexiblity 
rem without the need to change the basic setup.  Find more 
rem notes in the SSSG manual (if it ever gets written).

rem This batch file will also back up the data to another 
rem machine.  The data will be backed up to whatever is 
rem mounted on the "Z" drive.  This must be mounted 
rem before running this program.  

rem example:
rem go 172-05 17205 003 process batch.txt
rem casts must be named in the same way.  The first cast would be
rem 17205001, the 2nd 17205002, and so on...

rem There is an optional sixth command line entry that is used for the initial setup
rem of the processing.  Add #w as the sixth entry and the seabird software
rem will pause at the end of each section, allowing the operator to set up the 
rem processing, as well as saving the config files in the correct places.
rem example:
rem go 172-05 17205 003 process batch.txt #w

rem see also

rem BEGIN PROCESSING:
rem set screen to black on white, clear the screen.
color f0
cls
echo    -
echo Whoopee, lets back up the data!!!!
echo    -
echo This program will:
echo -Back up the cast to a different machine, typically \\lima\science\ctd_backup
echo -Process the data in a standard method
echo  and put the processed data in the \data\ctd\process\
echo -
echo The cast %3 on cruise %2 is about to be processed.
echo If this is not correct, hit control c now.  Otherwise 
pause
cls

rem First, backup the raw data.  Confirm if overwriting, and verify.
rem copy c:\ctd_data\"cruise directory"\"cruise number+cast number".* \\mike\ctd_data\*.*
rem use .hdr, .dat, .con, .bl, .nav or else repeated processing will fill the raw data 
rem dir with processed data.  It may be apropriate to comment out some lines depending....

echo Start Raw Data File Copying-
       copy /-y /v c:\data\ctd\%2%3.hdr   z:\*.* 
       copy /-y /v c:\data\ctd\%2%3.hex   z:\*.* 
       copy /-y /v c:\data\ctd\%2%3.xmlcon   z:\*.* 
       copy /-y /v c:\data\ctd\%2%3.bl    z:\*.* 
rem       copy /-y /v c:\data\ctd\%2%3.nav   z:\*.* 
echo End File copying
rem Now, set the files to read only.
echo change the files to read only
attrib +r z:\%2%3.*
echo done changing to read only

rem copy the .con file to the process directory for the rosette summary or others.
echo copy the .con file for this cast to the processing directory.
copy  /v c:\data\ctd\%2%3.XMLCON c:\data\ctd\%4\*.*

rem Process the data.  Call SeaBirds data processing software.
echo Start SbeBatch
call sbebatch c:\data\ctd\%4\%5 %1 %2 %3 %4 %6
echo Finished with SbeBatch